Új hozzászólás Aktív témák

• #54575 macilaci78 nagyúr Mutt #54574

  Új Válasz 2025-07-17 10:15:13 #54575

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  macilaci78

  nagyúr

  válasz Mutt #54574 üzenetére

  Köszi, ez be is vált!

• #54574 Mutt senior tag macilaci78 #54572

  Új Válasz 2025-07-16 22:45:14 #54574

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz macilaci78 #54572 üzenetére

  Szia,

  Ha A1-ben van a cikkszám és soha nem tartalmazhat "|" és "#" (pipe és hashtag) jeleket, akkor B1-ben ez a képlet:
  =HAHIBA(CSERE(BAL($A1;SZÖVEG.KERES("|";HELYETTE($A1&"-";"-";"|";OSZLOPOK($B:B)))-1);1;HAHIBA(SZÖVEG.KERES("#";HELYETTE($A1;"-";"#";OSZLOPOK($B:B)-1));0);"");"")

  Ezt tudod oldalra másolni, ahányszor kell az újabb részekért.
  
  Excel 2010-ben teszteltem, jónak kell lennie 2016-ban is.

  A képlet működése:
  1) van benne két HELYETTE amivel a kötőjeleket cserélgetjük le egyszer pipe-ra, ez fogja jelezni a szöveg minket érdeklő végét, illetve hashtag-re ami pedig a szöveg elejét jelzi. A HELYETTE függvényben meg lehet mondani, hogyha egy karakter többször előfordul, akkor melyik előfordulását cseréljük le. Az OSZLOPOK($B : B) adja meg, hogy éppen melyiket kell cserélni.
  2) Ezek után már csak a két marker közötti szöveg kivágása van vissza. Előbb BAL-al levágjuk a végét (a pipe-jelig tartjuk meg a szöveget), majd a CSERE függvénnyel a hashtag-ig (ami a kezdetet jelöli) mindent semmire cserélünk.

  Másik megoldás pedig egy 2 soros Power Query lenne, de ez csak akkor ha sok adatod van.

  Illetve VBA-val a Split függvénnyel pár soros kódot is lehetne használni.

  üdv

• #54573 lappy őstag macilaci78 #54572

  Új Válasz 2025-07-16 17:44:17 #54573

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  lappy

  őstag

  válasz macilaci78 #54572 üzenetére

  Szövegből oszlopok

• #54572 macilaci78 nagyúr

  Új Válasz 2025-07-16 17:08:54 #54572

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  macilaci78

  nagyúr

  Sziasztok!

  Van egy tételjegyzékem, aminek a cikkszám rovatában kötőjelekkel tagolt adatok vannak.
  Például: BLC-DBE1-L05-P2R-A14130-F
  Ezt szeretném szétdobni tagonként külön-külön oszlopba.
  Office 2016-ban mi ennek a menete?

  Köszi előre is!

• #54571 Fferi50 Topikgazda andreas49 #54570

  Új Válasz 2025-07-16 12:29:42 #54571

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Fferi50

  Topikgazda

  válasz andreas49 #54570 üzenetére

  Szia!
  A DÁTUMTÓLIG függvény helyett a NAPOK függvény használható. Az IF neve magyarul HA függvény.
  Üdv.

• #54570 andreas49 senior tag Mutt #54569

  Új Válasz 2025-07-16 10:36:23 #54570

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  andreas49

  senior tag

  válasz Mutt #54569 üzenetére

  Szia,
  Nálam (MS365 HU) nem kezeli a DÁTUMTÓLIG és az 'IF' függvényt, de az elöző megoldások szépen müködnek.

• #54569 Mutt senior tag andreas49 #54568

  Új Válasz 2025-07-15 23:11:37 #54569

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz andreas49 #54568 üzenetére

  Szia,

  Remek.

  A LET-ben is célszerű 365 helyett 365.25-el osztani, majd szorozni is.
  A napokat pedig tehetjuk egy KEREKÍTÉS-be, ahogy gondolom te is tetted.
  ... napok;KEREKÍTÉS(eredmeny-evek)*365,25;0);...

  Illetve van egy másik megoldás is, ami a rejtett DÁTUMTÓLIG/DATEDIF függvényt használja. Ha van 2 dátumod (1900 utánból), akkor ezzel ki lehet számolni az eltelt évek és napok pontos számát.
  =LET(adat1;A1;
adat2;A2;
evek;DÁTUMTÓLIG(adat1;adat2;"Y");
napok;DÁTUMTÓLIG(DÁTUM(ÉV(adat1)+evek;HÓNAP(adat1);NAP(adat1));adat2;"D");
evek&" ev"&IF(napok;" "&napok&" nap";""))

  üdv

• #54568 andreas49 senior tag andreas49 #54567

  Új Válasz 2025-07-15 19:52:12 #54568

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  andreas49

  senior tag

  válasz andreas49 #54567 üzenetére

  Közben sikerült megoldani, sok-sok köszönet a fentiekért.

• #54567 andreas49 senior tag Mutt #54566

  Új Válasz 2025-07-15 19:11:07 #54567

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  andreas49

  senior tag

  válasz Mutt #54566 üzenetére

  Szia,
  A LET-es megoldást tettem be, müködik, de a napokat is egész számra kellene kerekíteni (pl. most 18 év 285,999999999999 nap)

• #54566 Mutt senior tag andreas49 #54565

  Új Válasz 2025-07-15 18:15:50 #54566

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz andreas49 #54565 üzenetére

  Szia,

  Visszanézve a problémát a gond, hogy dátumokkal dolgozol, de az eredményed nem dátum, hanem a dátumok különbsége, így a formázás nem biztos hogy jó.

  1) Azonban kipróbálhatod cella vagy SZÖVEG függvényben ezt a formázást: "? ?/365"
  Az eredmény a fenti adatoknál ez lesz: "19 193/365", vagyis 19 év és 193 nap 365-ból.
  Ha zavar a végén a "/365" rész, akkor kell egy hosszabb képlet.

  2) LET-nél szerintem az a gond, hogy az első két sorban olyan változók vannak, amelyeknél a pontos cellákat kell megadnod ahol az adataid vannak. A #hiányzik arra utal, hogy olyan cellákra hivatkozik ahol nincs adat.

  Vagyis ha I2-ben van az 1999/01/01 és a másik dátumot L2 alapján találod meg, akkor így indul a képlet (aláhúzást tettem hogy feltünő legyen):
  =LET(adat1;I2;
  adat2;XKERES(L2;ALAP!$AA:$AA;ALAP!$AF:$AF); ....

  A LET-es képletet ha másolod, akkor a nem fixált cellahivatkozások (ahol nincs dollár jel) módosulnak, ezért célszerű a fixálni amit lehet.
  =LET(adat1;$I2;
adat2;XKERES($L2;Alap!$AA:$AA;Alap!$AF:$AF);
atalakit;LAMBDA(x;DÁTUM(BAL(x;4);KÖZÉP(x;5;2);JOBB(x;2)));
eredmeny;(atalakit(adat1)-atalakit(adat2))/365;
evek;INT(eredmeny);
napok;(eredmeny-evek)*365;
evek&" év"&HA(napok;" "&napok&" nap";""))

  Az újabb Excelben a fenti hosszú képletből csinálhatunk egy saját függvényt a LAMBDA segítségével, ez talán zavaró lehet csak akkor írom ide ha akarod és egyedül nem tudod megcsinálni.

  3) Ha nem akarsz LET-ezni akkor itt a csúnya képlet. 2x számolunk ki mindent, de először csak az éveket tartjuk meg (INT - egészrész), másodiknak pédig a tizedesrészt a napokhoz (MARADÉK). Itt ami még fontos, hogy a szökőévek miatt a 365-ös osztás nem elég pontos, 365.25-el 400 évig jók leszünk.
  =SZÖVEGÖSSZEFŰZÉS(" ";TRUE;INT((DÁTUM(BAL($I2;4);KÖZÉP($I2;5;2);JOBB($I2;2))-DÁTUM(BAL(XKERES(L2;Alap!AA:AA;Alap!AF:AF);4);KÖZÉP(XKERES(L2;Alap!AA:AA;Alap!AF:AF);5;2);JOBB(XKERES(L2;Alap!AA:AA;Alap!AF:AF);2)))/365.25);"év";KEREKÍTÉS(MARADÉK((DÁTUM(BAL($I2;4);KÖZÉP($I2;5;2);JOBB($I2;2))-DÁTUM(BAL(XKERES(L2;Alap!AA:AA;Alap!AF:AF);4);KÖZÉP(XKERES(L2;Alap!AA:AA;Alap!AF:AF);5;2);JOBB(XKERES(L2;Alap!AA:AA;Alap!AF:AF);2)))/365.25;1)*365.25;0);"nap")
  üdv

• #54565 andreas49 senior tag Mutt #54564

  Új Válasz 2025-07-15 09:59:56 #54565

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  andreas49

  senior tag

  válasz Mutt #54564 üzenetére

  Szia,
  Köszi a gyors választ, beírtam a 'SZÖVEG' függvényt :=SZÖVEG(KEREKÍTÉS((DÁTUM(BAL($I2;4);KÖZÉP($I2;5;2);JOBB($I2;2))-DÁTUM(BAL(XKERES(L2;Alap!AA:AA;Alap!AF:AF);4);KÖZÉP(XKERES(L2;Alap!AA:AA;Alap!AF:AF);5;2);JOBB(XKERES(L2;Alap!AA:AA;Alap!AF:AF);2)))/365;1);"éé. nnn") de az eredmény 00. Cs lett a 19. év és 'Cs' nem pedig a napok száma
  Az adatok ehhez az eredményhez: $I2 -> 19900101, 'AF:AF' -> 19700627
  MS365 Excel HU programot használok

• #54562 Mutt senior tag

  Új Válasz 2025-07-14 01:58:59 #54562

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  Hasznos opciót adtak a legújabb Excelhez, egyelőre csak a beta tesztelőknek érhető el.

  Mostantól a kimutatások/pivot automatikusan frissülhetnek amikor a forrásadatban változás van, ha ez engedélyezve van (alapból be van kapcsolva).
  Módosítani kimutatásonként a beállításoknál az Adatok fülön lehet megtenni, vagy alapértelmezetten a Fájl -> Adatok -> Alapértelmezett elrendezés szerkesztése -> Kimutatás beállításai alatt lehet.
  Sajna adatmodellt használó kimutatásokra nem érvényes ez a beállítás.

• #54561 jack982 senior tag Mutt #54560

  Új Válasz 2025-07-11 17:44:33 #54561

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  jack982

  senior tag

  válasz Mutt #54560 üzenetére

  Igen, a gpt nekem is jobb, pedig a copilot kézenfekvő lenne.

Új hozzászólás Aktív témák