2. Fórumok
  3. Egyéb hardverek
  4. Mikrokontrollerek Arduino környezetben (programozás, építés, tippek)

Hirdetés

!! SZERVERLEÁLLÁS, ADATVESZTÉS INFORMÁCIÓK !!
  • Téma összefoglaló
    Utoljára frissítve: 2024-07-25 09:13

    Mobilarena

    Arduino hardverrel és szoftverrel foglakozó téma. Minden mikrovezérlő ami arduinoval programozható, és minden arduino program, board, és hardverrel kapcsolatos kérdések helye.

Új hozzászólás Aktív témák

  • #5773 vargalex félisten Janos250 #5772
    Új Válasz #5773
    Új hozzászólás
    Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra
    Privát üzenet küldése

    vargalex

    félisten

    válasz Janos250 #5772 üzenetére

    Nyilván a jquery kicserélhető bármire (akár maradhat simán checkbox is, vagy saját CSS-t lehet gyártani pl. így), csak azért raktam bele, hogy kicsit pofásabb legyen a megjelenítés és maga a kód rövidebb. Nálam nem volt szempont az adatmennyiség.

    UPC-nél a DHCP net miatt tipikusan nem változik az IP cím. Ettől függetlenül nálam is van dyndns természetesen (már egy jó ideje az ipdns.hu-t használom). De a kérdésedet nem igazán értem... Ugyanis az UPC által adott IP-t nyilván a router WAN oldala kapja. Az állomások pedig egy belső IP címet. Mi közük az eszközöknek a külső IP-hez? Nekik a routerben statikus lease van beállítva a DHCP szervernél...

    És akkor a javított kód, mert a <body> és a <html> tag lezárása lemaradt (igaz, a böngészőket nem zavarja, automatikusan lezárják):

    #include <ESP8266WiFi.h>
    #include <WiFiClient.h>
    #include <ESP8266WebServer.h>

    #define DEFAULT_STATE LOW


    // Replace with your network credentials
    const char* ssid = "TP-Link";
    const char* password = "asdf1234";

    // GPIOs for controlling the relays
    uint8_t pin_relays[] = { D1, D2 };

    ESP8266WebServer server(80);

    // html page rendering
    void renderPage() {
    String webPage = "";
    String relay_state="";
    webPage = "<html><head><link rel=\"stylesheet\" href=\"https://code.jquery.com/mobile/1.4.5/jquery.mobile-1.4.5.min.css\">";
    webPage += "<script src=\"https://code.jquery.com/jquery-1.11.3.min.js\"></script>";
    webPage += "<script src=\"https://code.jquery.com/mobile/1.4.5/jquery.mobile-1.4.5.min.js\"></script></head>";
    webPage += "<body><h1>ESP8266 Relay Web Server</h1>";
    for (int relayIndex = 0; relayIndex<sizeof(pin_relays)/sizeof(uint8_t); relayIndex++) {
    relay_state="";
    if (digitalRead(pin_relays[relayIndex])) {
    relay_state="checked";
    }
    webPage += "<p>Relay #" + String(relayIndex) + " ( GPIO" + String(pin_relays[relayIndex]) + " ) <input type=\"checkbox\" " + relay_state + " data-role=\"flipswitch\" onchange=\"window.location.href='/?relay=" + String(relayIndex) + "'\"></p>";
    }
    webPage += "</body></html>";
    server.send(200, "text/html", webPage);
    }

    // handling requests
    void handle_root() {
    if (server.hasArg("relay")) {
    int relayIndex = server.arg("relay").toInt();
    digitalWrite(pin_relays[relayIndex], !digitalRead(pin_relays[relayIndex]));
    Serial.print("Relay ");
    Serial.print(relayIndex);
    Serial.print(" state changed to ");
    Serial.println(digitalRead(pin_relays[relayIndex]));
    }
    renderPage();
    }

    void setup(void){
    // preparing GPIOs
    for (int relayIndex = 0; relayIndex<sizeof(pin_relays)/sizeof(uint8_t); relayIndex++) {
    pinMode(pin_relays[relayIndex], OUTPUT);
    digitalWrite(pin_relays[relayIndex], DEFAULT_STATE);
    }

    //Turn on serial output
    delay(1000);
    Serial.begin(115200);
    WiFi.begin(ssid, password);
    Serial.println("");

    // Wait for connection
    while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
    }

    // logging to serial output
    Serial.println("");
    Serial.print("Connected to ");
    Serial.println(ssid);
    Serial.print("IP address: ");
    Serial.println(WiFi.localIP());

    // web server setup
    server.on("/", handle_root);
    server.begin();
    Serial.println("HTTP server started");
    }

    void loop(void){
    server.handleClient();
    }

    Amit még megjegyeznék, hogy ez a kód Wemos D1 mini-re készült. Sima ESP8266-on a D1, D2, stb. PIN-ek nincsenek definiálva (csak d1, d1 mini, nodemcu és wifinfo esetén).

Új hozzászólás Aktív témák