Új hozzászólás Aktív témák

• #52990 Mutt senior tag bozsozso #52983

  Új Válasz 2024-07-20 22:17:18 #52990

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz bozsozso #52983 üzenetére

  Szia,

  Ha nem lennének intervallum átfedések, akkor simán SZUMHATÖBB (vagy régebbi Excelben SZORZATÖSSZEG) megadná az eredményt, de mivel lehetnek átfedések így tömb-képlet kell.

  Ha nem MS365-öt használsz, akkor Excel 2016-tól használható az ÖSSZESíT függvény. D2 képlete (első 10 ezer sorban keresi az egyezést):
  =HAHIBA(INDEX($K$1:$K$10000;ÖSSZESÍT(14;6;SOR($G$2:G$10000)/(($G$2:$G$10000=A2)*($H$2:$H$10000=B2)*($I$2:$I$10000<=C2)*($J$2:$J$10000>=C2));1));"")

  Ha MS365-ön vagy akkor használjuk az újabb függvényeket:
  =LET(r;SZŰRŐ(K:K;(G:G=A2)*(H:H=B2)*(I:I<=C2)*(J:J>=C2));HAHIBA(INDEX(r;DARAB(r));""))

  

  üdv

• #52986 Fire/SOUL/CD félisten bozsozso #52983

  Új Válasz 2024-07-20 16:39:03 #52986

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Fire/SOUL/CD

  félisten

  válasz bozsozso #52983 üzenetére

  

  D2 képlete:

  =HAHIÁNYZIK(INDEX($K$2:$K$5;HOL.VAN(1;(A2=$G$2:$G$5)*(B2=$H$2:$H$5)*(C2>=$I$2:$I$5)*(C2<=$J$2:$J$5);0);0);"")

  Régebbi Excel-nél a képlet beírása/bemásolása után CTRL+SHIFT+ENTER, újabbaknál nem kell.

• #52984 Fferi50 Topikgazda bozsozso #52983

  Új Válasz 2024-07-20 12:30:48 #52984

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Fferi50

  Topikgazda

  válasz bozsozso #52983 üzenetére

  Szia!
  Most egy segédoszlopos javaslatot tudok mutatni - (bár láttam már itt tömbös megoldást is a kereső feltételek összevonására, de most nincs időm visszakeresni ):
  L2 cella képlete:=G2&H2&I2
  A D2 cella képlete:
  =HA(INDEX($J$1:$J$5;HOL.VAN(A2&B2&C2;$L$1:$L$5;1);1)>=C2;INDEX($K$1:$K$5;HOL.VAN(A2&B2&C2;$L$1:$L$5;1);1);"Nincs érvényes ár")
  Ahhoz, hogy jól működjön, a G:L táblázatot le kell rendezni az L oszlopra növekvően, ezért látod eltérő sorokban a tételeket a mintádhoz képest.
  A képlet húzható lefelé, vigyázz a $ jelekre (abszolút címzés az INDEX képletben). A képlet tekintettel van az érvényességi időre is.
  Üdv.

Új hozzászólás Aktív témák